Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames

Engine.ZoneInfo


00001
00002
00003
00004
00005
00006
00007
00008
00009
00010
00011
00012
00013
00014
00015
00016
00017
00018
00019
00020
00021
00022
00023
00024
00025
00026
00027
00028
00029
00030
00031
00032
00033
00034
00035
00036
00037
00038
00039
00040
00041
00042
00043
00044
00045
00046
00047
00048
00049
00050
00051
00052
00053
00054
00055
00056
00057
00058
00059
00060
00061
00062
00063
00064
00065
00066
00067
00068
00069
00070
00071
00072
00073
00074
00075
00076
00077
00078
00079
00080
00081
00082
00083
00084
00085
00086
00087
00088
00089
00090
00091
00092
00093
00094
00095
00096
00097
00098
00099
00100
00101
00102
00103
00104
00105
00106
00107
00108
00109
00110
00111
00112
00113
00114
00115
00116
00117
00118
00119
00120
00121
00122
00123
00124
00125
00126
00127
00128
00129
00130
00131
00132
00133
00134
00135
00136
00137
00138
00139
00140
00141
00142
00143
00144
00145
00146
00147
00148
00149
00150
00151
00152
00153
00154
00155
00156
00157
00158
00159
00160
00161
00162
00163
00164
00165
00166
00167
00168
00169
00170
00171
00172
00173
00174
00175
00176
00177
00178
00179
00180
00181
00182
00183
00184
00185
00186
00187
00188
00189
00190
00191
00192
00193
00194
00195
00196
00197
00198
00199
00200
00201
00202
00203
00204
00205
00206
00207
00208
00209
00210
00211
00212
//=============================================================================
// ZoneInfo, the built-in Unreal class for defining properties
// of zones.  If you place one ZoneInfo actor in a
// zone you have partioned, the ZoneInfo defines the 
// properties of the zone.
// This is a built-in Unreal class and it shouldn't be modified.
//=============================================================================
class ZoneInfo extends Info
    native
    nativereplication;

#exec Texture Import File=Textures\ZoneInfo.pcx Name=S_ZoneInfo Mips=Off Flags=2

//-----------------------------------------------------------------------------
// Zone properties.

var() name   ZoneTag;
var() vector ZoneGravity;
var() vector ZoneVelocity;
var() float  ZoneGroundFriction;
var() float  ZoneFluidFriction;
var() float  ZoneTerminalVelocity;
var() name   ZonePlayerEvent;
var   int    ZonePlayerCount;
var   int    NumCarcasses;
var() int    DamagePerSec;
var() name   DamageType;
var() localized string DamageString;
var(LocationStrings) localized string ZoneName;
var LocationID LocationID;  
var() int    MaxCarcasses;
var() sound  EntrySound;    //only if waterzone
var() sound  ExitSound;     // only if waterzone
var() class<actor> EntryActor;  // e.g. a splash (only if water zone)
var() class<actor> ExitActor;   // e.g. a splash (only if water zone)
var skyzoneinfo SkyZone; // Optional sky zone containing this zone's sky.

//-----------------------------------------------------------------------------
// Zone flags.

var()       bool   bWaterZone;   // Zone is water-filled.
var() const bool   bFogZone;     // Zone is fog-filled.
var() const bool   bKillZone;    // Zone instantly kills those who enter.
var()       bool   bNeutralZone; // Players can't take damage in this zone.
var()       bool   bGravityZone; // Use ZoneGravity.
var()       bool   bPainZone;    // Zone causes pain.
var()       bool   bDestructive; // Destroys carcasses.
var()       bool   bNoInventory;
var()       bool   bMoveProjectiles;    // this velocity zone should impart velocity to projectiles and effects
var()       bool   bBounceVelocity;     // this velocity zone should bounce actors that land in it

//-----------------------------------------------------------------------------
// Zone light.

var(ZoneLight) byte AmbientBrightness, AmbientHue, AmbientSaturation;
var(ZoneLight) color FogColor;
var(ZoneLight) float FogDistance;

var(ZoneLight) const texture EnvironmentMap;
var(ZoneLight) float TexUPanSpeed, TexVPanSpeed;
var(ZoneLight) vector ViewFlash, ViewFog;

//-----------------------------------------------------------------------------
// Reverb.

// Settings.
var(Reverb) bool bReverbZone;
var(Reverb) bool bRaytraceReverb;
var(Reverb) float SpeedOfSound;
var(Reverb) byte MasterGain;
var(Reverb) int  CutoffHz;
var(Reverb) byte Delay[6];
var(Reverb) byte Gain[6];

//-----------------------------------------------------------------------------
// Lens flare.

var(LensFlare) texture LensFlare[12];
var(LensFlare) float LensFlareOffset[12];
var(LensFlare) float LensFlareScale[12];

//-----------------------------------------------------------------------------
// per-Zone mesh LOD lighting control
 
// the number of lights applied to the actor mesh is interpolated between the following
// properties, as a function of the MeshPolyCount for the previous frame.
var() byte MinLightCount; // minimum number of lights to use (when MaxLightingPolyCount is exceeded)
var() byte MaxLightCount; // maximum number of lights to use (when MeshPolyCount drops below MinLightingPolyCount)
var() int MinLightingPolyCount;
var() int MaxLightingPolyCount;
// (NOTE: the default LOD properties (below) have no effect on the mesh lighting behavior)

//=============================================================================
// Network replication.

replication
{
    reliable if( Role==ROLE_Authority )
        ZoneGravity, ZoneVelocity, 
        // ZoneTerminalVelocity,
        // ZoneGroundFriction, ZoneFluidFriction,
        AmbientBrightness, AmbientHue, AmbientSaturation,
        TexUPanSpeed, TexVPanSpeed,
        // ViewFlash, ViewFog, // Not replicated because vectors replicated with elements rounded to integers
        bReverbZone,
        FogColor;
}

//=============================================================================
// Iterator functions.

// Iterate through all actors in this zone.
native(308) final iterator function ZoneActors( class<actor> BaseClass, out actor Actor );

//=============================================================================
simulated function LinkToSkybox()
{
    local skyzoneinfo TempSkyZone;

    // SkyZone.
    foreach AllActors( class 'SkyZoneInfo', TempSkyZone, '' )
        SkyZone = TempSkyZone;
    foreach AllActors( class 'SkyZoneInfo', TempSkyZone, '' )
        if( TempSkyZone.bHighDetail == Level.bHighDetailMode )
            SkyZone = TempSkyZone;
}

//=============================================================================
// Engine notification functions.

simulated function PreBeginPlay()
{
    Super.PreBeginPlay();

    // call overridable function to link this ZoneInfo actor to a skybox
    LinkToSkybox();
}

function Trigger( actor Other, pawn EventInstigator )
{
    if (DamagePerSec != 0)
        bPainZone = true;
}

// When an actor enters this zone.
event ActorEntered( actor Other )
{
    local actor A;
    local vector AddVelocity;

    if ( bNoInventory && Other.IsA('Inventory') && (Other.Owner == None) )
    {
        Other.LifeSpan = 1.5;
        return;
    }

    if( Pawn(Other)!=None && Pawn(Other).bIsPlayer )
        if( ++ZonePlayerCount==1 && ZonePlayerEvent!='' )
            foreach AllActors( class 'Actor', A, ZonePlayerEvent )
                A.Trigger( Self, Pawn(Other) );

    if ( bMoveProjectiles && (ZoneVelocity != vect(0,0,0)) )
    {
        if ( Other.Physics == PHYS_Projectile )
            Other.Velocity += ZoneVelocity;
        else if ( Other.IsA('Effects') && (Other.Physics == PHYS_None) )
        {
            Other.SetPhysics(PHYS_Projectile);
            Other.Velocity += ZoneVelocity;
        }
    }
}

// When an actor leaves this zone.
event ActorLeaving( actor Other )
{
    local actor A;
    if( Pawn(Other)!=None && Pawn(Other).bIsPlayer )
        if( --ZonePlayerCount==0 && ZonePlayerEvent!='' )
            foreach AllActors( class 'Actor', A, ZonePlayerEvent )
                A.UnTrigger( Self, Pawn(Other) );
}

defaultproperties
{
     ZoneGravity=(Z=-950.000000)
     ZoneGroundFriction=8.000000
     ZoneFluidFriction=1.200000
     ZoneTerminalVelocity=2500.000000
     MaxCarcasses=3
     bMoveProjectiles=True
     AmbientSaturation=255
     TexUPanSpeed=1.000000
     TexVPanSpeed=1.000000
     SpeedOfSound=8000.000000
     MasterGain=100
     CutoffHz=6000
     Delay(0)=20
     Delay(1)=34
     Gain(0)=150
     Gain(1)=70
     MinLightCount=6
     MaxLightCount=6
     MinLightingPolyCount=1000
     MaxLightingPolyCount=5000
     bStatic=True
     bNoDelete=True
     bAlwaysRelevant=True
     Texture=Texture'Engine.S_ZoneInfo'
     NetUpdateFrequency=2.000000
}

Overview Package Class Source Class tree Glossary
previous class      next class frames      no frames
Class file time: Do 19.5.2005 19:42:12.000 - Creation time: Fr 7.6.2013 13:16:28.159 - Created with UnCodeX